ARGOMENTO:

Ciao Luca, questo è corretto ?

Sell next bar at lowest(low, BS) stop ;
end ;

E' la scrittura per il trailing stop ?

Hai ragione, per qualche motivo ho fatto un ragionamento erratissimo...
mettiamo giù in questa maniera il traling stop per le posizioni long, cioè lo stop si sposta stando, man mano, sul minimo della barra precedente....

Sell next bar at low stop ;
end ;

Domande:
1) su che strumenti vorresti far girare il TS?
2) potresti spiegarmi un pò meglio il traling stopè che vorresti?

Luca

Ciao Luca,ho provato a inserire la stringa per il trailing stop ma il sistema non la legge.
Sto lavorando con il Forex, come puoi vedere sono agli inizi e dopo aver fatto delle strategie d'ingresso mi stavo focalizzando sulla gestione della posizione.
Per prima cosa volevo testare il trailing stop rispetto a uno stop tradizionale per vedere la differenza nel back test.
Come trailing mi riferivo :
POSIZIONE SELL
-il trailing deve salire seguendo Low con stop iniziale monetario esempio 200 $
POSIZIONE LONG
-il trailing deve salire seguendo High con stop iniziale monetario esempio 200 $
Poi invece volevo testare il trailing non più su uno stop monetario ma su uno stop iniziale di volatilità tipo ATR a 14 periodi.
Spero di essere stato chiaro, grazie.

Ciao Carlo,
a dire il vero pure io ho appena cominciato con questo linguaggio, questi sono i miei primi passi...
Per ora ti posto il tuo codice con le chiusure in traling con l'ATR...



[IntrabarOrderGeneration = false]
{Dichiarazione delle variabili e degli input}
Inputs: Length(25), StdDevUp(2.0), StdDevDn(-2.0), ATRLength( 14 ), NumATRs( 1 );
Vars: UpBand(0), DnBand(0),MP(0), ATRCalc( 0 ), TT( 0 ), PosHigh( 0 ), PosLow( 0 );

{Assegnamento delle variabili}

UpBand = BollingerBand(C, Length, StdDevUp);
DnBand = BollingerBand(C, Length, StdDevDn);
ATRCalc = AvgTrueRange( ATRLength ) * NumATRs ;
MP = MarketPosition ;
TT = TotalTrades ;

{Enter Long}
if High > UpBand Then Buy ("BE") Next Bar at Market;
{Enter Short}
If Low < DnBand Then Sell Short ("SE") Next Bar at Market;

{Chiusure Long}
if MP = 1 then
begin
if TT <> TT[1] or MP[1] <> 1 or High > PosHigh then
PosHigh = High ;
Sell ( "AtrLX" ) next bar at PosHigh - ATRCalc stop ;
end
else
Sell ( "AtrLX-eb" ) next bar at High - ATRCalc stop ;

{Chiusure Short}
if MP = -1 then
begin
if TT <> TT[1] or MP[1] <> -1 or Low < PosLow then
PosLow = Low ;
Buy To Cover ( "AtrSX" ) next bar at PosLow + ATRCalc stop ;
end
else
Buy To Cover ( "AtrSX-eb" ) next bar at Low + ATRCalc stop ;



Ora provo a vedere per lo "stop a 200$" cosa riesco a combinarti...

Ciao
Luca

Ciao Luca anche io sto lavorando sulle bande, ti giro la scrittura per gli stop monetari è molto semplici il problema è che non riesco a inserire il traling stop che segua massimi e minimi di posizione.


{Dichiarazione delle variabili e degli input}
Inputs: Length(25), StdDevUp(2.0), StdDevDn(-2.0),stoploss(200),profittarget(200);
Vars: UpBand(0), DnBand(0), MP(0);

{Assegnamento delle variabili}
MP = Marketposition;

UpBand = BollingerBand(C, Length, StdDevUp);
DnBand = BollingerBand(C, Length, StdDevDn);


{Enter Long}
If C > UpBand Then Buy ("BE") Next Bar at Market;
{Enter Short}
If C < DnBand Then Sell Short ("SE") Next Bar at Market;


Setprofittarget(profittarget);
setstoploss(stoploss);

Carlo, spero di aver compreso a pieno la tua ideaa per il tralingstop per il sistema "stop a 200$".

Da subiro ti avverto che siccomi operi sul FX io al posto dei 200$ monetari che mi chiedevi ho piazzato un input in Pips, poco male fin che operi con eurusd dove con 0,1lotti un pip vale 1$ così abbiamo aggirato il problema

Per la chiusura delle posizioni Bay mi chiedevi:

POSIZIONE LONG
-il trailing deve salire seguendo High con stop iniziale monetario esempio 200 $

quindi il sistema entra in posizione all'open della barra ed in questa tiene lo stop iniziale a 200pips($) di distanza dall'high e così fa via via che si forman le barre. Per ciò avrai lo stop sui long che agisce facendo il calcolo: High (precedente) - 200pips.



[IntrabarOrderGeneration = false]

{Dichiarazione delle variabili e degli input}
Inputs: Length(25), StdDevUp(2.0), StdDevDn(-2.0), StopPip(200);
Vars: UpBand(0), DnBand(0),MP(0), SP (0), TT(0),PosLow( 0 ), PosHigh( 0 );

{Assegnamento delle variabili}

UpBand = BollingerBand(C, Length, StdDevUp);
DnBand = BollingerBand(C, Length, StdDevDn);
SP = StopPip / 10000 ;
MP = MarketPosition ;
TT = TotalTrades ;

{Enter Long}
if High > UpBand Then Buy ("BE") Next Bar at Market;
{Enter Short}
If Low < DnBand Then Sell Short ("SE") Next Bar at Market;

{Exit Long}
if MP = 1 then
begin
if TT <> TT[1] or MP[1] <> 1 or High > PosHigh then
PosHigh = High ;
Sell ( "AtrLX" ) next bar at PosHigh - SP stop ;
end
else
Sell ( "AtrLX-eb" ) next bar at High - SP stop ;

{Exit Short}
if MP = -1 then
begin
if TT <> TT[1] or MP[1] <> -1 or Low < PosLow then
PosLow = Low ;
Buy To Cover ( "AtrSX" ) next bar at PosLow + SP stop ;
end
else
Buy To Cover ( "AtrSX-eb" ) next bar at Low + SP stop ;


Il sistema è al quanto grezzo, premetto che operazioni long e short in questo TS non coesistono.

Spero di aver interpretato a dovere la tua idea...
Luca

Forse in questa maniera abbiamo lo stop monetario anche in input....

[IntrabarOrderGeneration = false]

{Dichiarazione delle variabili e degli input}
Inputs: Length(25), StdDevUp(2.0), StdDevDn(-2.0), stoploss(200);
Vars: UpBand(0), DnBand(0),MP(0), SP (0), TT(0),PosLow( 0 ), PosHigh( 0 );

{Assegnamento delle variabili}

UpBand = BollingerBand(C, Length, StdDevUp);
DnBand = BollingerBand(C, Length, StdDevDn);
//SP = StopPip / 10000 ;
MP = MarketPosition ;
TT = TotalTrades ;

{Enter Long}
if High > UpBand Then Buy ("BE") Next Bar at Market;
{Enter Short}
If Low < DnBand Then Sell Short ("SE") Next Bar at Market;

{Exit Long}
if MP = 1 then
begin
if TT <> TT[1] or MP[1] <> 1 or High > PosHigh then
PosHigh = High ;
Sell ( "AtrLX" ) next bar at PosHigh - stoploss stop ;
end
else
Sell ( "AtrLX-eb" ) next bar at High - stoploss stop ;

{Exit Short}
if MP = -1 then
begin
if TT <> TT[1] or MP[1] <> -1 or Low < PosLow then
PosLow = Low ;
Buy To Cover ( "AtrSX" ) next bar at PosLow + stoploss stop ;
end
else
Buy To Cover ( "AtrSX-eb" ) next bar at Low + stoploss stop ;

Setstoploss (stoploss)

Ho inserito il codice, e guardato le singole operazioni di entrata e di uscita e anche in questo caso il trailing non è attivo, infatti tutte le uscite in perdita hanno l'importo di -€ 200 nonostante il prezzo si sia mosso a favore creando nuovi (LOW e HIGH) per poi invertire posizione portandoci in loss e quindi chiudendo il trade con un semplice stop loss monetario fisso di 200€.Ti inoltro copia.

Ciao Luca, ti risulta ?

Attenzione Carlo, perché in automatico Tradestation nei test ti negozia un lotto quindi 200$ di stop sono 20pips, alzando lo stop nei settaggi da 200 a 2000$ io ho riscontrato qualcosa del genere



Ogni modo potrebbe esserci qualcosa nella strategia che non va come vorresti tu, il consiglio che ti dò è quello di tradurre il traling stop che ti ho scritto in un indicatore così da poter avere il riscontro visivo che tutto va come lo avevi immaginato...
Scusami per il ritardo nella risposta...

Luca